From ccc39ce37f69d9e788f8d9eccf678607ef68ba12 Mon Sep 17 00:00:00 2001
From: Teddy Reed <teddy@prosauce.org>
Date: Tue, 5 Jul 2016 00:10:44 -0700
Subject: [PATCH] recipes-devtools: Add uefi-firmware-parser Python module

---
 meta-luv/classes/pypi.bbclass                 | 30 +++++++++++++++++++
 .../images/core-image-efi-initramfs.bb        |  2 +-
 .../uefi-firmware-parser_1.6.bb               | 12 ++++++++
 3 files changed, 43 insertions(+), 1 deletion(-)
 create mode 100644 meta-luv/classes/pypi.bbclass
 create mode 100644 meta-luv/recipes-devtools/uefi-firmware-parser/uefi-firmware-parser_1.6.bb

diff --git a/meta-luv/classes/pypi.bbclass b/meta-luv/classes/pypi.bbclass
new file mode 100644
index 00000000000..54fced0662e
--- /dev/null
+++ b/meta-luv/classes/pypi.bbclass
@@ -0,0 +1,30 @@
+def pypi_package(d):
+    bpn = d.getVar('BPN', True)
+    if bpn.startswith('python-'):
+        return bpn[7:]
+    elif bpn.startswith('python3-'):
+        return bpn[8:]
+    return bpn
+
+PYPI_PACKAGE ?= "${@pypi_package(d)}"
+PYPI_PACKAGE_EXT ?= "tar.gz"
+
+def pypi_src_uri(d):
+    package = d.getVar('PYPI_PACKAGE', True)
+    package_ext = d.getVar('PYPI_PACKAGE_EXT', True)
+    package_hash = d.getVar('PYPI_PACKAGE_HASH', True)
+    pv = d.getVar('PV', True)
+    if package_hash:
+        return 'https://pypi.python.org/packages/%s/%s/%s/%s-%s.%s' % (
+            package_hash[:2], package_hash[2:4], package_hash[4:], package, pv, package_ext)
+    else:
+        return 'https://pypi.python.org/packages/source/%s/%s/%s-%s.%s' % (
+            package[0], package, package, pv, package_ext)
+
+PYPI_SRC_URI ?= "${@pypi_src_uri(d)}"
+
+HOMEPAGE ?= "https://pypi.python.org/pypi/${PYPI_PACKAGE}/"
+SECTION = "devel/python"
+SRC_URI += "${PYPI_SRC_URI}"
+S = "${WORKDIR}/${PYPI_PACKAGE}-${PV}"
+
diff --git a/meta-luv/recipes-core/images/core-image-efi-initramfs.bb b/meta-luv/recipes-core/images/core-image-efi-initramfs.bb
index 9fbea18d979..288d6942648 100644
--- a/meta-luv/recipes-core/images/core-image-efi-initramfs.bb
+++ b/meta-luv/recipes-core/images/core-image-efi-initramfs.bb
@@ -11,7 +11,7 @@ IMAGE_INSTALL = "\
     "
 
 X86_ADDITIONS = "chipsec python-codecs python-subprocess kexec vmcore-dmesg bits \
-                 kernel-modules"
+                 kernel-modules uefi-firmware-parser"
 
 IMAGE_INSTALL_append_qemux86 = "${X86_ADDITIONS}"
 IMAGE_INSTALL_append_qemux86-64 = "${X86_ADDITIONS} ndctl"
diff --git a/meta-luv/recipes-devtools/uefi-firmware-parser/uefi-firmware-parser_1.6.bb b/meta-luv/recipes-devtools/uefi-firmware-parser/uefi-firmware-parser_1.6.bb
new file mode 100644
index 00000000000..1c221177644
--- /dev/null
+++ b/meta-luv/recipes-devtools/uefi-firmware-parser/uefi-firmware-parser_1.6.bb
@@ -0,0 +1,12 @@
+SUMMARY = "Python module uefi-firmware for parsing/extracting UEFI structures"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://PKG-INFO;md5=18abe1c5026e14a25f210a99c232300e"
+
+DEPENDS = "python-dev"
+
+SRC_URI[md5sum] = "561cc83f9bf48f5c976398e47a3ba9df"
+SRC_URI[sha256sum] = "8c15f0406e8f9ea1b0d1d0e7107199cbaaa996b5cffdc1437789291adb81ce52"
+PYPI_PACKAGE_HASH = "9dcf4bfe2b207e214bfedc2f57ced8d4742fad2da70ec67db562ab023373daf8"
+
+PYPI_PACKAGE = "uefi_firmware"
+inherit pypi setuptools